Plot of the equilibrium shape of an elastic ring subjected to a given pressure σ

Contents of this notebook :
Part I. Definitions and input data
Part II. Determination of the values of the parameters q and η
Part III. Plot of the equilibrium shape
Part IV. Confirmation of the closure conditions

Part I. Definitions and input data

Definitions from Section 5. Analytic expressions for the ring curvatures and slope angles

μ=(1/4)((α^2)+(β^2)+(γ^2)+α β+α γ+β γ);

γ=-(( α+β)/2)+I η ; δ=-(( α+β)/2)-I η;

λ=(1/4)(Sqrt[A B]); k=(1/2)-((4 (η^2)+(3 α+β) (α+3 β))/(2 A B));

A=(Sqrt[4 (η^2)+(((3 α+β))^2)]); B=(Sqrt[4 (η^2)+(((α+3 β))^2)]);

T=(4/λ) EllipticK[k];

Left-hand side of the closure condition -- formula (42)

CC= (((A+B) (α-β))/(2 λ (A-B))) EllipticPi[-((((A-B))^2)/(4 A B)),k] +  ((A β-B α)/(λ (A-B))) EllipticK[k];

New parametrization -- formula (44)

α=((4 σ)/((η^2)+(q^2)))-q; β=((4 σ)/((η^2)+(q^2)))+q;

Input data

σ=4; n=2;

Part II. Determination of the values of the parameters q and η

Contour plots of the transcendental equations (42) and (43)

F1=ContourPlot[CC==(π/(2 n)),{q,0.00001`,10},{η,0.00001`,10},ContourStyle->GrayLevel[0.7`]];

F2=ContourPlot[(T/4)==(π/(2 n)),{q,0.00001`,10},{η,0.00001`,10}];

Show[F1,F2]

Identification of the values of the parameters q and η

qguess=6;  ηguess=6;

Comment: The guess values qguess and  ηguess for q and η, respectively, are appropriate for n≤5 and σ≤100. For other values of n and σ, qguess and  ηguess should be increased accordingly.

FR=FindRoot[{CC==(π/(2 n)),(T/4)==(π/(2 n))},{q,ηguess},{η,ηguess},AccuracyGoal->100,WorkingPrecision->250,MaxIterations->2000];

FR1=Extract[FR,1];

FR2=Extract[FR,2];

q=Abs[q/.FR1];

η=Abs[η/.FR2];

Part III. Plot of the equilibrium shape

Expressions for the curvature (38), its derivative and the slope angle (39)

κ[s_]=(((A β+B α)-(A β-B α) JacobiCN[s λ,k])/((A+B)-(A-B) JacobiCN[s λ,k]));

κ1[s_]=(∂_s) κ[s];

φ[s_]= ((A β-B α)/(A-B)) s+(((A+B) (α-β))/(2 λ (A-B))) EllipticPi[-((((A-B))^2)/(4 A B)),JacobiAmplitude[s λ,k],k]+((α-β)/(2 λ (Sqrt[k+((((A-B))^2)/(4 A B))])))  ArcTan[(Sqrt[k+((((A-B))^2)/(4 A B))])((JacobiSN[s λ,k])/(JacobiDN[s λ,k]))];

Parametric equations (25)

X[s_]=(1/σ) κ1[s] Cos[φ[s]]+(( ((κ[s])^2)-2 μ)/(2 σ)) Sin[φ[s]];

Y[s_]=(1/σ) κ1[s] Sin[φ[s]]-(( ((κ[s])^2)-2 μ)/(2 σ)) Cos[φ[s]];

Plot

ParametricPlot[{X[s],Y[s]},{s,0, n T},AspectRatio->Automatic, Axes -> False,PlotStyle->Hue[0,0,0]]

Part IV. Confirmation of the closure conditions

N[X[0]-X[n T]]

N[Y[0]-Y[n T]]

X1[s_]=(∂_s) X[s]; Y1[s_]=(∂_s) Y[s];

N[X1[0]-X1[n T]]

N[Y1[0]-Y1[n T]]

N[CC-(π/(2 n))]

N[(T/4)-(π/(2 n))]