Plot of a 2-fold equilibrium shape of an elastic ring with a line of contact

Contents of this notebook :
Part I. Definitions
Part II. Scale reduction and determination of the contact values of the parameters q and η for the ring of the reduced length
Part III. Plot of the equilibrium shape with a line of contact
Part IV. Confirmation of the closure conditions and the length

Part I. Definitions

Definitions from Section 5. Analytic expressions for the ring curvatures and slope angles

μ=(1/4)((α^2)+(β^2)+(γ^2)+α β+α γ+β γ);

γ=-(( α+β)/2)+I η ; δ=-(( α+β)/2)-I η;

λ=(1/4)(Sqrt[A B]); k=(1/2)-((4 (η^2)+(3 α+β) (α+3 β))/(2 A B));

A=(Sqrt[4 (η^2)+(((3 α+β))^2)]); B=(Sqrt[4 (η^2)+(((α+3 β))^2)]);

T=(4/λ) EllipticK[k];

Part II. Scale reduction and determination of the contact values of the parameters q and η for the ring of the reduced length

New parametrization -- formula (44)

α=((4 σ)/((q^2)+(η^2)))-q; β=((4 σ)/((q^2)+(η^2)))+q;

Input data (contact pressure (Subscript[σ, cn]) = 5.247)

σ=10;

The contact parameters for a ring of length 2π
 (These can be determined using the notebook Contact.nb. Here, 150-digit precision is used to ensure sufficient accuracy of the computations.)

σ2cn=5.24688696253147410778074124609097163258638933591611584220903310804981945124299493945309269787373609532838258820005361893505668994473616922033250525002937526487256678`150.;

q2cn=2.46033820877534060613347575148409876082124194509898963471396777155725369485116932431341102593786980645635977505507543060940075783275762917440994634660439609154506389`150.;

η2cn=2.88417049939461659319507711605367856172766041414189928565011026684003542016386670914793001001466308645379707188129098552181785035420470823073611839964927121848616116`150.;

Scalling

f=(((((σ2cn)/σ)))^(1/3));

q=q2cn/f; η=η2cn/f;

Part III. Plot of the equilibrium shape with a line of contact

Expressions for the curvature (38), its derivative and the slope angle (39)

κ[s_]=(((A β+B α)-(A β-B α) JacobiCN[s λ,k])/((A+B)-(A-B) JacobiCN[s λ,k]));

κ1[s_]=(∂_s) κ[s];

φ[s_]= ((A β-B α)/(A-B)) s+(((A+B) (α-β))/(2 λ (A-B))) EllipticPi[-((((A-B))^2)/(4 A B)),JacobiAmplitude[s λ,k],k]+((α-β)/(2 λ (Sqrt[k+((((A-B))^2)/(4 A B))])))  ArcTan[(Sqrt[k+((((A-B))^2)/(4 A B))])((JacobiSN[s λ,k])/(JacobiDN[s λ,k]))];

Parametric equations (25)

X[s_]=(1/σ) κ1[s] Cos[φ[s]]+(( ((κ[s])^2)-2 μ)/(2 σ)) Sin[φ[s]];

Y[s_]=(1/σ) κ1[s] Sin[φ[s]]-(( ((κ[s])^2)-2 μ)/(2 σ)) Cos[φ[s]];

Plot

Calculation of the length LL of the line segment

LL=π(1-f);

Plot of the two parts of the ring of reduced length with a contact point positioned at a distance LL

F1=ParametricPlot[{{X[s]+(LL/2),Y[s]},{X[s+T]-(LL/2),Y[s+T]}},{s,0,T},AspectRatio->Automatic, Axes -> False,PlotStyle->{{Black, Thick},{Black, Thick}}];

Plot of the line segment

F2=ParametricPlot[{ξ,0},{ξ,-(LL/2),(LL/2)}, AspectRatio->Automatic, Axes -> False,PlotStyle->{Black, Thick}];

Combining these two plots gives the ring shape with a line of contact

FC=Show[ F1,F2]

Part IV. Confirmation of the closure conditions and the length

N[(((A+B) (α-β))/(2 λ (A-B))) EllipticPi[-((((A-B))^2)/(4 A B)),k]+((A β-B α)/(λ (A-B))) EllipticK[k]-(π/4)]

N[T-π f]

N[2 T+2 LL-2 π]