Plot of a 3-fold equilibrium shape of an elastic ring with lines of contact

Contents of this notebook :
Part I. Definitions
Part II. Scale reduction and determination of the contact values of the parameters q, η and s1 for the ring of the reduced length
Part III. Plot of the equilibrium shape with lines of contact
Part IV. Confirmation of the contact conditions and the length

Part I. Definitions

Definitions from Section 5. Analytic expressions for the ring curvatures and slope angles

μ=(1/4) ((α^2)+(β^2)+(γ^2)+α β+α γ+β γ);

γ=-((α+β)/2)+I η ;

λ=(1/4)(Sqrt[A B]); k= (1/2)-((4 (η^2)+(3 α+β) (α+3 β))/(2 A B));

A= (Sqrt[4 (η^2)+(((3 α+β))^2)]); B= (Sqrt[4 (η^2)+ (((α+3 β))^2)]) ;

T=(4/λ)  EllipticK[k];

New parametrization -- formula (44)

α=((4 σ)/((η^2)+(q^2)))-q; β=((4 σ)/((η^2)+(q^2)))+q;

Input data (contact pressure (Subscript[σ, cn])=21.65)

σ=80;

Part II. Scale reduction and determination of the contact values of the parameters q, η and s1 for the ring of the reduced length

The contact parameters for a ring of length 2π
 (These can be determined using the notebook Contact.nb. Here, 150-digit precision is used to ensure sufficient accuracy of the computations.)

σ3cn= 21.65026512798701067113104569711670511346323992281411315519287578411660732037568617480744545460046938756159163166973277170365836037810755452172551135475008449394148505`150.;

q3cn=4.86993910697729947955786538799505506362241824445908259283896544184008262879875999271002077710150910879250886158681809827089316041284527189544107650493987342282688715`150.;

η3cn=4.45122976396510827576222531782233067997553272123689493574270581798223974814420887832864499500419055794974463166529574829471967385352733167109613402536257029075532883`150.;

s13cn =0.19186046401674607770292907932930992041588354151745365534174413491612652988810128825910147795743363307125221468110415312880151050660668241873643292465386948037425543;

Scalling

f=(((((σ3cn)/σ)))^(1/3));

q=q3cn/f; η=η3cn/f; s1 = s13cn f;

Part III. Plot of the equilibrium shape with lines of contact

Expressions for the curvature (38), its derivative and the slope angle (39)

κ[s_]=(((A β+B α)-(A β-B α) JacobiCN[s λ,k])/((A+B)-(A-B) JacobiCN[s λ,k]));

κ1[s_]=(∂_s) κ[s];

∅[s_]= ((A β-B α)/(A-B)) s+(((A+B) (α-β))/(2 λ (A-B))) EllipticPi[-((((A-B))^2)/(4 A B)),JacobiAmplitude[s λ,k],k]+((α-β)/(2 λ (Sqrt[k+((((A-B))^2)/(4 A B))])))  ArcTan[(Sqrt[k+((((A-B))^2)/(4 A B))])((JacobiSN[s λ,k])/(JacobiDN[s λ,k]))];

Parametric equations (25)

X[s_]=(1/σ) κ1[s] Cos[∅[s]]+(( ((κ[s])^2)-2 μ)/(2 σ)) Sin[∅[s]];

Y[s_]=(1/σ) κ1[s] Sin[∅[s]]-(( ((κ[s])^2)-2 μ)/(2 σ)) Cos[∅[s]];

Plot

Calculation of the total length LL of all line segments

LL=((2 π)/3)(1-f);

Plots of the parts of the ring shape

F1=ParametricPlot[{{X[s],Y[s]},{X[s+T],Y[s+T]},{X[s+2 T],Y[s+2 T]}},{s,0,s1},AspectRatio->Automatic, Axes -> False,PlotStyle->{{Black,Thick},{Black,Thick}, {Black,Thick}}];

s2=T-s1;

F2=ParametricPlot[{{X[s],Y[s]},{X[s+T],Y[s+T]},{X[s+2 T],Y[s+2 T]}},{s,s2,T},AspectRatio->Automatic, Axes -> False,PlotStyle->{{Black,Thick},{Black,Thick}, {Black,Thick}}];

ξ1=(Sqrt[1+(LL/(Sqrt[((X[s1])^2)+((Y[s1])^2)]))]);

FL=ParametricPlot[{{X[s1] ξ,Y[s1] ξ},{X[s1+T] ξ,Y[s1+T] ξ},{X[s1+2 T] ξ,Y[s1+2 T] ξ}}, {ξ,1,ξ1},AspectRatio->Automatic, Axes -> False,PlotStyle->{{Black,Thick},{Black,Thick}, {Black,Thick}}];

F3=ParametricPlot[{{(ξ1-1)  X[s1]+ X[s],(ξ1-1) Y[s1]+Y[s]},{(ξ1-1)  X[s1+T]+ X[s+T],(ξ1-1) Y[s1+T]+Y[s+T]},{(ξ1-1)  X[s1+2 T]+ X[s+2 T],(ξ1-1) Y[s1+2 T]+Y[s+2 T]}},{s,s1,s2},AspectRatio->Automatic, Axes -> False,PlotStyle->{{Black,Thick},{Black,Thick}, {Black,Thick}}];

Combination of these plots gives the ring shape with lines of contact

FC=Show[F3, F1, F2,FL]

Part IV. Confirmation of the contact conditions and the length

Left-hand side of the closure condition -- formula (42)

N[ (((A+B) (α-β))/(2 λ (A-B))) EllipticPi[-((((A-B))^2)/(4 A B)),k]+((A β-B α)/(λ (A-B))) EllipticK[k]-(π/(2 3))]

N[(T/4)-(π/(2 3)) f]

N[∅[s1]-((( π)/3)-(( π)/2))]

N[3 T+3 LL-2 π]