Plot of the equilibrium shapes of an elastic ring with lines of contact

Case n=6

Contents of this notebook :
Part I. Definitions
Part II. Scale reduction and determination of the contact values of the parameters q, η and s1 for the ring of the reduced length
Part III. Plot of the equilibrium shape with lines of contact
Part IV. Confirmation of the contact conditions and the length

Part I. Definitions

Definitions from Section 4. Analytic expressions for the ring curvatures and slope angles

μ=(1/4) ((α^2)+(β^2)+(γ^2)+α β+α γ+β γ);

γ=-((α+β)/2)+I η ;

λ=(1/4)(Sqrt[A B]); k= (1/2)-((4 (η^2)+(3 α+β) (α+3 β))/(2 A B));

A= (Sqrt[4 (η^2)+(((3 α+β))^2)]); B= (Sqrt[4 (η^2)+ (((α+3 β))^2)]) ;

T=(4/λ)  EllipticK[k];

Left-hand side of the closure condition -- formula (42)

CC= (((A+B) (α-β))/(2 λ (A-B))) EllipticPi[-((((A-B))^2)/(4 A B)),k]+((A β-B α)/(λ (A-B))) EllipticK[k];

New parametrization -- formula (44)

α=((4 σ)/((η^2)+(q^2)))-q; β=((4 σ)/((η^2)+(q^2)))+q;

Input data (contact pressure (Subscript[σ, cn])=161.077)

σ=400; n=6;

Part II. Scale reduction and determination of the contact values of the parameters q, η and s1 for the ring of the reduced length

The contact parameters for a ring of length 2π
 (These can be determined using the notebook Contact.nb. Here, 150 digit precision is used to ensure sufficient accuracy of the computations.)

σ6cn= 161.07722943692184491578329334092200748235030058258564711487157930203733039680889303369069686581004338065379779287798582511763337085077864699641769519729826155141804242`150.;

q6cn=11.69385472888823329298329238873885506273067707451907761909037185674983127531579890004897327622859206932494171520401976337059995170419787053584538041720527028129051377`150.;

η6cn=8.95637659464547129514698955180735594867505315831642874100368680846747674621963486496444312082194807977888306856712068130130843787719855540964241230754861529481465431`150.;

s16cn =0.13419366211590373768098323403559842838776504739456249100967054904451062622078931167206292421716687803409225838404989640122109175806545763159910411375954052414151;

Scalling

f=(((((σ6cn)/σ)))^(1/3));

q=q6cn/f; η=η6cn/f; s1 = s16cn f;

Part III. Plot of the equilibrium shape with lines of contact

Expressions for the curvature, its derivative and the slope angle

κ[s_]=(((A β+B α)-(A β-B α) JacobiCN[s λ,k])/((A+B)-(A-B) JacobiCN[s λ,k]));

κ1[s_]=(∂_s) κ[s];

∅[s_]= ((A β-B α)/(A-B)) s+(((A+B) (α-β))/(2 λ (A-B))) EllipticPi[-((((A-B))^2)/(4 A B)),JacobiAmplitude[s λ,k],k]+((α-β)/(2 λ (Sqrt[k+((((A-B))^2)/(4 A B))])))  ArcTan[(Sqrt[k+((((A-B))^2)/(4 A B))])((JacobiSN[s λ,k])/(JacobiDN[s λ,k]))];

Parametric equations

X[s_]=(1/σ) κ1[s] Cos[∅[s]]+(( ((κ[s])^2)-2 μ)/(2 σ)) Sin[∅[s]];

Y[s_]=(1/σ) κ1[s] Sin[∅[s]]-(( ((κ[s])^2)-2 μ)/(2 σ)) Cos[∅[s]];

Plot

Calculation of the total length LL of all line segments

LL=((2 π)/n)(1-f);

Plots of the parts of the ring shape

F1=ParametricPlot[{{X[s],Y[s]},{X[s+T],Y[s+T]},{X[s+2 T],Y[s+2 T]},{X[s+3 T],Y[s+3 T]},{X[s+4 T],Y[s+4 T]},{X[s+5T],Y[s+5 T]}},{s,0,s1},AspectRatio->Automatic, Axes -> False,PlotStyle->{{Black,Thick},{Black,Thick}, {Black,Thick}, {Black,Thick},{Black,Thick}, {Black,Thick}}];

s2=T-s1;

F2=ParametricPlot[{{X[s],Y[s]},{X[s+T],Y[s+T]},{X[s+2 T],Y[s+2 T]},{X[s+3 T],Y[s+3 T]},{X[s+4 T],Y[s+4 T]},{X[s+5T],Y[s+5 T]}},{s,s2,T},AspectRatio->Automatic, Axes -> False,PlotStyle->{{Black,Thick},{Black,Thick}, {Black,Thick}, {Black,Thick},{Black,Thick}, {Black,Thick}}];

ξ1=(Sqrt[1+(LL/(Sqrt[((X[s1])^2)+((Y[s1])^2)]))]);

FL=ParametricPlot[{{X[s1] ξ,Y[s1] ξ},{X[s1+T] ξ,Y[s1+T] ξ},{X[s1+2 T] ξ,Y[s1+2 T] ξ},{X[s1+3 T] ξ,Y[s1+3 T] ξ},{X[s1+4 T] ξ,Y[s1+4 T] ξ},{X[s1+5 T] ξ,Y[s1+5 T] ξ}}, {ξ,1,ξ1},AspectRatio->Automatic, Axes -> False,PlotStyle->{{Black,Thick},{Black,Thick}, {Black,Thick}, {Black,Thick},{Black,Thick}, {Black,Thick}}];

F3=ParametricPlot[{{(ξ1-1)  X[s1]+ X[s],(ξ1-1) Y[s1]+Y[s]},{(ξ1-1)  X[s1+T]+ X[s+T],(ξ1-1) Y[s1+T]+Y[s+T]},{(ξ1-1)  X[s1+2 T]+ X[s+2 T],(ξ1-1) Y[s1+2 T]+Y[s+2 T]},{(ξ1-1)  X[s1+3 T]+ X[s+3 T],(ξ1-1) Y[s1+3 T]+Y[s+3 T]},{(ξ1-1)  X[s1+4 T]+ X[s+4 T],(ξ1-1) Y[s1+4 T]+Y[s+4 T]},{(ξ1-1)  X[s1+5 T]+ X[s+5 T],(ξ1-1) Y[s1+5 T]+Y[s+5 T]}},{s,s1,s2},AspectRatio->Automatic, Axes -> False,PlotStyle->{{Black,Thick},{Black,Thick}, {Black,Thick}, {Black,Thick},{Black,Thick}, {Black,Thick}}];

Combination of these plots gives the ring shape with lines of contact

FC=Show[F3, F1, F2,FL]

Export["C:\\Lines_6_fold.eps", FC];

Part IV. Confirmation of the contact conditions and the length

N[CC-(π/(2 n))]

N[(T/4)-(π/(2 n)) f]

N[∅[s1]-((( π)/n)-(( π)/2))]

N[n T+n LL-2 π]